Totals in ALV using CL_SALV_TABLE

0
6894

In this tutorial we will learn how to add totals to the ALV report using CL_SALV_TABLE.

To add totals,

  • Get the Aggregation object of the ALV using GET_AGGREGATIONS().
  • Add Aggregation for a particular column by calling the method ADD_AGGREGATION().

Classes used :

  1. CL_SALV_TABLE and
  2. CL_SALV_AGGREGATIONS.

Create a program in SE38 and copy the below code

REPORT  zsl_oop_alv_row_color.
*----------------------------------------------------------------------*
*      Add Totals in ALV report using factory class CL_SALV_TABLE      *
*----------------------------------------------------------------------*
*                    www.saplearners.com                               *
*----------------------------------------------------------------------*
*----------------------------------------------------------------------*
*       CLASS lcl_sflight DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_sflight DEFINITION.

  PUBLIC SECTION.
    TYPES: BEGIN OF lty_sflight,
           carrid	         TYPE s_carr_id,
           connid	         TYPE s_conn_id,
           fldate	         TYPE s_date,
           price           TYPE s_price,
           currency	       TYPE s_currcode,
           planetype       TYPE s_planetye,
           seatsmax	       TYPE s_seatsmax,
           seatsocc	       TYPE s_seatsocc,
           END OF lty_sflight.

    METHODS: get_sflight_data,
             get_alv_instance,
             display.

    DATA: lo_alv      TYPE REF TO cl_salv_table,
          gt_sflight TYPE STANDARD TABLE OF lty_sflight.

ENDCLASS.                    "lcl_sflight DEFINITION

*----------------------------------------------------------------------*
*       CLASS lcl_sflight IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_sflight IMPLEMENTATION.

* Get SFLIGHT data
  METHOD get_sflight_data.
    SELECT carrid connid fldate price currency planetype seatsmax
           seatsocc INTO TABLE me->gt_sflight
                    FROM sflight UP TO 10 rows.
  ENDMETHOD.                    "get_sflight_data

* Get ALV instance
  METHOD get_alv_instance.
    TRY.
        CALL METHOD cl_salv_table=>factory
          IMPORTING
            r_salv_table = lo_alv
          CHANGING
            t_table      = gt_sflight.
      CATCH cx_salv_msg.
    ENDTRY.

  ENDMETHOD.                    "get_alv_instance

* Display ALV
  METHOD display.
    CALL METHOD lo_alv->display.
  ENDMETHOD.                    "display
ENDCLASS.                    "lcl_sflight IMPLEMENTATION



START-OF-SELECTION.
  DATA: lo_cl_sflight     TYPE REF TO lcl_sflight,
        lo_aggregations   TYPE REF TO cl_salv_aggregations.

  CREATE OBJECT lo_cl_sflight.

* Get the Data for ALV report
  lo_cl_sflight->get_sflight_data( ).

* Get ALV instance
  lo_cl_sflight->get_alv_instance( ).

*// Add Totals
*// 1.Get Aggregation object of the ALV
  CALL METHOD lo_cl_sflight->lo_alv->get_aggregations
    RECEIVING
      value = lo_aggregations.

*// 2.Specify the column name for totals
  TRY.
      CALL METHOD lo_aggregations->add_aggregation
        EXPORTING
          columnname  = 'PRICE'
          aggregation = if_salv_c_aggregation=>total.
    CATCH cx_salv_data_error .
    CATCH cx_salv_not_found .
    CATCH cx_salv_existing .
  ENDTRY.

* Display ALV report
  lo_cl_sflight->display( ).

Output without Totals:

alv1

Output with Totals:

alv1